Subversion中文站 - SVN|TortoiseSVN|论坛|教程|下载|安装|配置

论坛最新主题
svn 似乎不能提交文件权限的修改求文件mod_dav_svn.so RapidSVN rpm包下载 Apache + SVN用户认证配置问题 SH域名成为时尚新宠

在线情况
现在有 94 位访客在线和1 位会员在线

Windows下其他有用的钩子实例

作者： rocksun

2006-11-22

1，强制写日志

在每次提交的时候写明提交的目的是一个很好的习惯，Subversion默认没有提供，但是可以通过钩子实现：

将下面的代码存为放到版本库的hooks目录下即可，当你不写日志提交的话就会报告错误。（如果你下载使用，需要修改SVN_BINDIR为你的Subversion安装的程序目录）

@echo off

set SVN_BINDIR=d:\Subversion\bin

setlocal

set REPOS=%1

set TXN=%2

rem check that logmessage contains at least 10 characters

%SVN_BINDIR%\svnlook log "%REPOS%" -t "%TXN%" | findstr ".........." > nul

if %errorlevel% gtr 0 goto err

exit 0

:err

echo Empty log message not allowed. Commit aborted! 1>&2

exit 1

注：修改自Subversion官方网站。

2，可以修改历史日志

历史上的日志写的不好，我们希望修改，默认对Subversion是不允许的，并且会提示需要创建post-revprop-change钩子。最简单的方式是创建一个空白的post-revprop-change.bat文件放到版本库的hooks目录下，但是这种方式不够严格，用户具备了修改所有属性的权利，例如修改作者的权利（可以提交垃圾然后栽赃嫁祸了）。所以要限制用户只能修改日志，所以有了下面的代码，将其存为pre-revprop-change.bat放到版本库的hooks目录下即可。

@ECHO OFF

set repos=%1

set rev=%2

set user=%3

set propname=%4

set action=%5

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

:: Only allow changes to svn:log. The author, date and other revision

:: properties cannot be changed

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

if /I not '%propname%'=='svn:log' goto ERROR_PROPNAME

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

:: Only allow modifications to svn:log (no addition/overwrite or deletion)

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

if /I not '%action%'=='M' goto ERROR_ACTION

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

:: Make sure that the new svn:log message contains some text.

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

set bIsEmpty=true

for /f "tokens=*" %%g in ('find /V ""') do (

set bIsEmpty=false

)

if '%bIsEmpty%'=='true' goto ERROR_EMPTY

goto :eof

:ERROR_EMPTY

echo Empty svn:log properties are not allowed. >&2

goto ERROR_EXIT

:ERROR_PROPNAME

echo Only changes to svn:log revision properties are allowed. >&2

goto ERROR_EXIT

:ERROR_ACTION

echo Only modifications to svn:log revision properties are allowed. >&2

goto ERROR_EXIT

:ERROR_EXIT

exit 1

网友评论

强制写日志
作者 bakerchen 于 2007-07-27 16:19:17

强制写日志這段代碼放在任意的一個文件中就可以了嗎?

作者 rocksun 于 2006-11-29 17:52:13

非常感谢，已经更改...

可以修改历史日志中的钩子文件名应为pre-re
作者 wyc82 于 2006-11-29 13:33:20

可以修改历史日志中的钩子文件名不应为：post-revprop-change.bat
而应是：pre-revprop-change.bat

只有注册用户才能发表评论。
请登录或注册

最近更新 ( 2006-11-29 )

< 上一篇		下一篇 >